Some currencies already exist, like [1], [2] and they are all instances of currency [3]. Unfortunately there are no links to all instances from [3].
So is there a possibility to get this list from Wikidata?
Yes, there is.
There are several ways to get this list:
You can, in Wikidata website, look at every entity that has a link to currency (Q8142): https://www.wikidata.org/wiki/Special:WhatLinksHere/Q8142. The problem of this is that you will have some entities that makes a link to currency other than instance of.
The best way is to use an external tool called AutoList, developed by a German guy called Magnus Manske. The link of his tool is here: https://tools.wmflabs.org/autolist/autolist1.html
This tool uses a query language WDQ. Its documentation is here: https://wdq.wmflabs.org/api_documentation.html
Here is how it works:
The property "instance of" has the identifier P31.
The value "currency" has the identifier Q8142.
If you want every Wikidata entity with the condition (P31 == Q8142) equals true:
claim[31:8142] in the form field called Query;The official dataset on currencies is maintained by the ISO 4217 standard. You can download the currency dataset in XML or Excel format at this link:
SPARQL query for all currencies ever
Stanislav Kralin gave a good query in the coomments, with some indentation added by me:
select distinct ?currency ?currencyLabel {
?currency wdt:P31/wdt:P279* wd:Q8142
service wikibase:label { bd:serviceParam wikibase:language "en" }
}
ORDER BY ?currencyLabel
The constants mean:
The way the wdt:P31/wdt:P279* wd:Q8142 pattern works is:
For example, it could be that Bitcoin is an instance of a cryptocurrency, and cryptocurrency is a subclass of currency. This is not the actual current modeling, just an example.
I've given more details on this question expanding on the "Humans born in New York City" sample query which is analogous: could be born in New York, or born in Brooklyn, or born in some hospital in New York.
Finding only current official currencies of existing countries
The output of the above query, while complete, is likely not the most useful to most people, as it contains all sorts of ancient, experimental, and crypto currencies, many of which don't even have an English wikipedia page and as a result no label.
Here's an initial attempt at getting only current currencies of countries:
SELECT
?currency
(GROUP_CONCAT(DISTINCT ?currencyIsoCode; SEPARATOR=", ") AS ?currencyIsoCodes)
?currencyLabel
(GROUP_CONCAT(DISTINCT ?countryLabel; SEPARATOR=", ") AS ?countries)
WHERE {
?country wdt:P31/wdt:P279* wd:Q6256. # is country
?country p:P38 ?countryHasCurrency.
?countryHasCurrency ps:P38 ?currency.
?countryHasCurrency wikibase:rank ?countryHasCurrencyRank.
OPTIONAL {
?currency p:P498 ?currencyHasIsoCode.
?currencyHasIsoCode ps:P498 ?currencyIsoCode.
}
FILTER NOT EXISTS {?country wdt:P576 ?countryAbolished}
FILTER NOT EXISTS {?currency wdt:P576 ?currencyAbolished}
FILTER NOT EXISTS {?currency wdt:P582 ?currencyEndTime}
FILTER NOT EXISTS {?countryHasCurrency pq:P582 ?countryHasCurrencyEndtime}
FILTER (?countryHasCurrencyRank != wikibase:DeprecatedRank)
FILTER (!bound(?currencyHasIsoCode) || ?currencyHasIsoCode != wikibase:DeprecatedRank)
# TODO makes query take timeout? Why? Needed to exclude PLZ.
#FILTER NOT EXISTS {?currencyHasIsoCode pq:P582 ?currencyHasIsoCodeEndtime}
SERVICE wikibase:label {
bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en".
?currency rdfs:label ?currencyLabel .
?country rdfs:label ?countryLabel .
}
}
GROUP BY ?currency ?currencyLabel
ORDER BY ?currencyIsoCodes ?currencyLabel
Sorting by the ISO 4217 code helps tremendously to identify weird currencies that have no ISO code and might be wrong.
The first 3 with empty ISO codes and the first 3 with non-empty ISO codes are:
| currency | currencyLabel | currencyIsoCodes | countries |
|---|---|---|---|
| Q131723 | bitcoin | El Salvador | |
| Q4406 | Tuvaluan dollar | Tuvalu | |
| Q507737 | Cook Islands dollar | Cook Islands | |
| Q200294 | AED | United Arab Emirates dirham | United Arab Emirates |
| Q199471 | AFN | afghani | Afghanistan |
| Q125999 | ALL | Albanian lek | Albania, Sovereign State of the Bektashi Order |
and there is a total of 160 results.
ISO currently has 169 regular country currencies, so we are missing a few, it would be good to understand every single difference and try to fix them.
Some comments on the empty ones that I see:
There's also a Wikipedia category for coins without ISO codes.
Basically all country pages are semi-protected on Wikidata so I can't fix them right now.
OK now comparing with ISO with some quick Bash. Currency codes Wikidata missed from ISO:
If I try to replace wd:Q6256 (country) with wd:Q56061 (administrative territorial entity) the query times out. This also happens if I try to just get all administrative territorial entity and nothing else, so there must be a billion of them.
Currency codes Wikidata had in excess from ISO at some point in my queries:
