How to get all Wikidata items in a country?

Question

Using SPARQL I want to show all French embassies in Liberia (spoiler: there is exactly one)

So I wrote this naive query:

SELECT ?item WHERE {
    ?item wdt:P17 wd:Q1014.    # country: Liberia
    ?item wdt:P31 wd:Q3917681. # instance of: embassy
    ?item wdt:P137 wd:Q142.    # operated by: France
}

PROBLEM: It finds zero items. Even though there is such an item in Liberia, more exactly it is located in the administrative territorial entity of "Monrovia", which itself has a country value of "Liberia".

More generally, I want to get ALL Wikidata items that are in a particular country. How to do?

It must also work if you replace Q1014 (Liberia) with Q183 (Germany), which is even trickier.

Answer 1

Not as straight forward as it seems. Here's a first attempt which works for the Liberian example.

    SELECT ?item ?territory ?territoryLabel 
WHERE {
    ?item wdt:P31 wd:Q3917681. # instance of: embassy
    ?item wdt:P137 wd:Q142.    # operated by: France
    ?item wdt:P131 ?territory .
    ?territory wdt:P17 wd:Q1014 . #countries seem to have a wdt:P17 property of their id
      SERVICE wikibase:label {
    bd:serviceParam wikibase:language "en" .
}
  }
ORDER BY ?item

Gives duplicates for countries that have changed. See Minsk as an example of a territory in many former countries. A generic query would need to filter these out.

Answer 2

This query does the trick:

SELECT DISTINCT ?item WHERE {
    ?item wdt:P131*/wdt:P17 wd:Q1014.    # country: Liberia (recursive)
    ?item wdt:P31 wd:Q3917681.           # instance of: embassy
    ?item wdt:P137 wd:Q142.              # operated by: France
}

It includes all sub-regions of the country.
It does not show any duplicates.