Get Wikipedia URLs (sitelinks) in Wikidata SPARQL query

Question

I can use the following query to list all sovereign states via the Wikidata query interface:

PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>

SELECT ?cid ?country WHERE {
    ?cid wdt:P31 wd:Q3624078 .
    OPTIONAL {
        ?cid rdfs:label ?country filter (lang(?country) = "en") .
    }
}

The result listing contains the Wikidata entity ID and the English label, if available. I'd like to also query the URL of the corresponding English Wikipedia article if it exists. As far as I can tell, Wikipedia URLs are not properties of a Wikidata entity and I have no idea how I can express a relation between a Wikidata entity and Wikipedia URL in the SPARQL query.

Answer 1

Try this one:

prefix schema: <http://schema.org/>
PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>

SELECT ?cid ?country ?article WHERE {
    ?cid wdt:P31 wd:Q3624078 .
    OPTIONAL {
        ?cid rdfs:label ?country filter (lang(?country) = "en") .
    }
    OPTIONAL {
      ?article schema:about ?cid .
      ?article schema:inLanguage "en" .
      FILTER (SUBSTR(str(?article), 1, 25) = "https://en.wikipedia.org/")
    }
} 

More details about sitelinks are in the RDF docs. Note that right now the only way to distinguish between Wikipedia links and other English links (like sources, news, etc.) is by URL match, thus a somewhat ugly filter.

Answer 2

On 18. April 2016 the ticket "More efficient SPARQL queries for sitelinks" brought us a better way: schema:isPartOf.

?sitelink schema:about ?item .
?sitelink schema:inLanguage "en" .     
?sitelink schema:isPartOf <https://en.wikipedia.org/> .

Your full query now looks like this:

PREFIX schema: <http://schema.org/>
PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>

SELECT ?cid ?country ?article WHERE {
    ?cid wdt:P31 wd:Q3624078 .
    OPTIONAL {
      ?cid rdfs:label ?country filter (lang(?country) = "en") .
    }
    OPTIONAL {
      ?article schema:about ?cid .
      ?article schema:inLanguage "en" .
      ?article schema:isPartOf <https://en.wikipedia.org/> .
    }
}