Weird results in search from wikidata

Question

I ve this query, which i want to find every instance of human with name Jose (already a first name like John, very common) in wikidata spanish, and then I get only 10 results. I believe is the way of the subquery, like if I made the filter of my 50 previous results, but I can't move the conditions without breaking the query.

my query:

SELECT * WHERE {
  SERVICE wikibase:mwapi {
      bd:serviceParam wikibase:api "EntitySearch" .
      bd:serviceParam wikibase:endpoint "www.wikidata.org" .
      bd:serviceParam mwapi:search "josé" .
      bd:serviceParam mwapi:language "es" .
      ?item wikibase:apiOutputItem mwapi:item .
      ?num wikibase:apiOrdinal true .
  }

  ?item (wdt:P279|wdt:P31) ?type
   FILTER (?type = wd:Q5)
OPTIONAL { ?item wdt:P569 ?fecha_de_nacimiento. }
    FILTER(?fecha_de_nacimiento > "1900-12-31T00:00:00Z"^^xsd:dateTime)
} ORDER BY ASC(?num)

and my edit, is similar in result:

SELECT * WHERE {
  SERVICE wikibase:mwapi {
      bd:serviceParam wikibase:api "EntitySearch" .
      bd:serviceParam wikibase:endpoint "www.wikidata.org" .
      bd:serviceParam mwapi:search "josé" .
      bd:serviceParam mwapi:language "es" .
      ?item wikibase:apiOutputItem mwapi:item .
      ?num wikibase:apiOrdinal true .
      ?item (wdt:P279|wdt:P31) ?type
   FILTER (?type = wd:Q5)
  }


OPTIONAL { ?item wdt:P569 ?fecha_de_nacimiento. }
    FILTER(?fecha_de_nacimiento > "1900-12-31T00:00:00Z"^^xsd:dateTime)
} ORDER BY ASC(?num)

Answer 1

...like if I made the filter of my 50 previous results...

Wikibase:mwapi supports the limit parameter of the Entity Search service:

SELECT ?item ?label ?order WHERE {
  VALUES (?type ?name) {(wd:Q5 "Jose")}
  SERVICE wikibase:mwapi {
      bd:serviceParam wikibase:api "EntitySearch" ;
                      wikibase:endpoint "www.wikidata.org" ;
                      mwapi:language "es" ;
                      mwapi:search ?name ;
                      mwapi:limit "50" .
      ?item wikibase:apiOutputItem mwapi:item .
      ?order wikibase:apiOrdinal true .
      ?label wikibase:apiOutput mwapi:label .
  }
  ?item wdt:P31 ?type .
  ?item wdt:P569 ?date. 
  FILTER (?date > "1900-12-31T00:00:00Z"^^xsd:dateTime) 
} ORDER BY ASC(?order) LIMIT 10

Try it!

As you can see, results are still weird (but try e. g. "José Mourinho" instead of "José").

Possibly you should add some filtering using CONTAINS.

If you want to search people by their given names, probably you should use the wd:P735 property, however, there is no fast way to get most "popular" or "relevant" results.