3

I have the Tiger places (dark green), which I believe contains census designated places. I also have the Census Bureau's Cartographic Boundary Shapefiles - Places (Incorporated Places and Census Designated Places) (light green). Those two basically overlap just perfectly as shown here:

http://i.imgur.com/u8XGhGO.jpg

When I look at the same area on Google Maps, the unincorporated community of Aberdeen, California shows up (as well as Blackrock and some others):

enter image description here

Are there any sources out there for unincorporated communities? When I check the USPS zipcode lookup I get a zipcode for Aberdeen, and I imagine I can use something like the Census Bureau's ZIP code spatial data to get an idea of what communities are in what zipcodes, but that really doesn't give me the actual centroid or boundary of Aberdeen.

migrated from gis.stackexchange.com May 30 '17 at 21:45

This question came from our site for cartographers, geographers and GIS professionals.

  • This may be better asked at the Open Data Stack Exchange. – PolyGeo May 30 '17 at 21:32
  • Any chance you could move it over there? – Eric May 30 '17 at 21:42
  • 2
    I'm not sure I understand your question...Is this what you want (press Run below the query form)? – Stanislav Kralin May 31 '17 at 9:05
  • 1
    These and probably these fields are available. You need to learn SPARQL to retrieve their values. I think, you can ask additional questions here or on SO. In this question, let you write which fields you need, and I'll try to write example query. – Stanislav Kralin May 31 '17 at 19:20
  • 1
    nicely done! @StanislavKralin you should answer this question with your comment and radpin should accept it...as long as it is still correct. Sorry if this seems like I'm lecturing, just trying to get questions answered and cleared. – albert Jun 5 '17 at 22:15
2

Using Wikidata SPARQL Endpoint:

SELECT ?a ?aLabel ?point WHERE {
?a wdt:P31 wd:Q17343829 ;
   wdt:P625 ?point
SERVICE wikibase:label { bd:serviceParam wikibase:language "en" . }
}

Place this pseudo-comment — #defaultView:Map — anywhere in the query above, if you want to display results on the map.

Not all unincorporated communities has coordinates in Wikidata. If you do not want to exclude these unincorporated communities from results, use OPTIONAL:

SELECT ?a ?aLabel ?point WHERE {
?a wdt:P31 wd:Q17343829 .
OPTIONAL { ?a wdt:P625 ?point }
SERVICE wikibase:label { bd:serviceParam wikibase:language "en" . }
}

These unincorporated communities has no coordinates in Wikidata:

SELECT ?a ?aLabel WHERE {
?a wdt:P31 wd:Q17343829 .
FILTER NOT EXISTS { ?a wdt:P625 ?point }
SERVICE wikibase:label { bd:serviceParam wikibase:language "en" . }
}

You can add missing coordinates yourself (e.g. for Carolan, Arcansas).

Using DBPedia SPARQL endpoint:

SELECT ?a SAMPLE(str(?aLabel)) AVG(?lat) AVG(?long) WHERE
{
?a dbo:type dbr:Unincorporated_area ;
   rdfs:label ?aLabel ;
   geo:lat  ?lat ;
   geo:long ?long .
FILTER (lang(?aLabel) = "en")
} GROUP BY ?a

The number of unincorporated communities in DBPedia is less than in Wikidata. You can add missing communities creating their pages in Wikipedia.

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.